PinLab Docs

Добавим функцию записи данных в файл. Для записи выберем формат файла CSV. CSV (от англ. Comma-Separated Values — значения, разделённые запятыми) — текстовый формат, предназначенный для представления табличных данных. Строка таблицы соответствует строке текста, которая содержит одно или несколько полей, разделенных запятыми.

Одна строка файла будет соответствовать одному измерению температуры. Первым числом будет температура в комнате, а вторым — на улице. Разделителем данных в строке будет символ точки с запятой. Пример записей в файл:

23,2;12,0
24,2;13,0
24,1;13,2

Формат CSV имеет широкое распространение, его можно открыть в Excel или OpenOffice Calc и построить графики. Что мы и сделаем.

Схема эксперимента остается неизменной Рисунок 1. Монтажная схема эксперимента

Добавим функцию записи данных в файл. Для записи выберем формат файла CSV. CSV (от англ. Comma-Separated Values — значения, разделённые запятыми) — текстовый формат, предназначенный для представления табличных данных. Строка таблицы соответствует строке текста, которая содержит одно или несколько полей, разделенных запятыми.

Одна строка файла будет соответствовать одному измерению температуры. Первым числом будет температура в комнате, а вторым — на улице. Разделителем данных в строке будет символ точки с запятой. Пример записей в файл:

23,2;12,0
24,2;13,0
24,1;13,2

Формат CSV имеет широкое распространение, его можно открыть в Excel или OpenOffice Calc и построить графики. Что мы и сделаем.

Схема эксперимента остается неизменной Рисунок 1. Монтажная схема эксперимента

Exp42.ino

#include <OneWire.h>
#include <DallasTemperature.h>
#include <LCDI2C_Multilingual.h>
#include <LittleFS.h>
 
#define ACD_PIN A0
#define BUS_PIN 12
#define DEFAULT_I2C_ADDR 0x3F // Или 0x27 в зависимости от твоей платы IoT
 
const int Bcoef = 3950;
const int R1 = 10000;
const int Rtnom = 10000;
const float T0 = 273.15;
 
OneWire oneWire(BUS_PIN);
DallasTemperature sensors(&oneWire);
LCDI2C_Generic lcd(DEFAULT_I2C_ADDR, 16, 2);
 
void setup() {
  Serial.begin(9600);
  Serial.println();
  sensors.begin();
  lcd.init(); 
  lcd.setBacklight(0); 
 
  LittleFS.format();
  LittleFS.begin();
 
  Serial.print("Writing data to file");
 
  for(int i = 0; i < 30; i++) {
    int value = analogRead(ACD_PIN);
    float R2 = (-R1 * value) / (value - 1023);
    float temp_outodor = 1 / (log(R2 / Rtnom) / Bcoef + 1/(25 + T0)) - T0;
 
    sensors.requestTemperatures(); 
    float temp_inroom = sensors.getTempCByIndex(0);
 
    lcd.clear();
    lcd.print("Outodor: ");
    lcd.println(temp_outodor, 1);
    lcd.print("In room: ");
    lcd.print(temp_inroom, 1);  
 
    String s = String(temp_outodor, 1) + ";" +  String(temp_inroom, 1) + "\n";
    s.replace('.', ',');
 
    File f = LittleFS.open("/temp_data.csv", "a");
    f.print(s);
    f.close();
 
    Serial.print(".");
    delay(2000); 
  }
 
  Serial.println();
  Serial.println("Reading data from file");
 
  File f = LittleFS.open("/temp_data.csv", "r");
  while(f.available()) Serial.write(f.read());
  f.close();
}
 
void loop() {
}

По сравнений с прошлой программой мы перенесли код работы с датчиками из бесконечного цикла в конечный, добавили код для работы с файлом и подготовки данных для записи в него. Рассмотрим эти части подробнее.

Создаем строку из чисел для записи в файл. Строка состоит из температуры в комнате, символа разделителя данных ;, температуры на улице и символа перехода на новую строку \n. Без \n всё записывалось бы в одну строку.

  String s = String(temp_outodor, 1) + ";" +  String(temp_inroom, 1) + "\n";

Arduino использует точку как десятичный разделитель. Однако русские версии программ, вроде Excel и OpenOffice Calc используют запятую. Поэтому, чтобы в дальнейшем работать с файлом в этих программах, нам нужно заменить точку на запятую:

  s.replace('.', ',');

Далее идет работа с файлом. Открываем файл. Дескриптор открытого файла оказывается в переменной f.

  File f = LittleFS.open("/temp_data.csv", "a");

Файл открывается с помощью оператора open() в качестве параметров ему передается имя файла и опции, описывающие что мы собираемся делать с файлом. Здесь может быть указано r для чтения, w для записи файла и a для дополнения файла. Мы используем a, в таком случае при открытии файл не будет очищен, а будет дополняться новыми записями в конце. Если файл не существует, то при открытии с помощью w или a файл будет автоматически создан.

Записываем в файл строку:

  f.print(s);

После записи закрываем файл:

  f.close();

Далее открываем файл уже в режиме чтения - r, в цикле while печатаем строки файла в последовательный порт пока файл не закончиться, и закрываем файл.

  File f = LittleFS.open("/temp_data.csv", "r");
  while(f.available()) Serial.write(f.read());
  f.close();

Запустим программу и дождемся ее выполнения. Это займет 1 минуту, после чего записанные в файл данные будут выведены в последовательный порт.

К сожалению при использовании Arduino IDE отсутствует удобный способ скачать созданный файл на компьютер. Поэтому предлагаем создать с помощью блокнота текстовый файл, скопировать в него выведенные в последовательный порт данные и сохранить файл с расширением .csv.

Читать такие данные достаточно неудобно, поэтому откроем их с помощью Excel:

Excel автоматически распознал формат CSV и занес данные с «комнатного» датчика в столбец A, и данные с «уличного» датчика в столбец B. Построим графики температуры: Вставка График

Датчик DS18B20 измерял у нас температуру в комнате, а термистор мы через некоторое время после начала эксперимента погрузили в стакан с теплой водой. Температура термистора резко возросла. Вода в стакане постепенно остывала, что мы хорошо видим на графике.