В предыдущих уроках, мы писали достаточно простые программы. Их простота заключалась в линейности логики алгоритма. В главном цикле проверялось состояние кнопки и сразу же изменялось состояние светодиода. Задержка, если необходимо, вносилась с помощью функции delay(). Этот пример отлично работает, с небольшими схемами и примитивной логикой. Но если хочется чего-то большего, то старыми средствами уже не обойтись и от использования delay() придется отказаться.

Ранее, чтобы проверить состояние вывода микроконтроллера мы использовали команду вроде value_a = digitalRead(ENC_A). Чтобы узнать изменилось ли состояние по сравнению с предыдущей проверкой мы хранили ее результат в переменной и сравнивали. А если нам нужно отслеживать короткие изменения состояния пинов, то проверять их состояние нужно как можно чаще. Все это заставляет микроконтроллер тратить процессорное время на простую работу с сигналом.

Оказывается есть отличное решение этой проблемы. Микроконтроллер умеет аппаратно отслеживать изменения состояния выводов. Пока процессор занят чем-то по-настоящему важным за состоянием пинов следит специальная электронная схема. Как только изменение происходит, схема сигнализирует об этом процессору, который прерывает исполнение основной программы для того, чтобы обработать это прерывание — исполнить небольшой код, реагирующий на событие.

Прерывание — это сигнал (событие), который заставляет контроллер прекратить выполнение текущей задачи и приступить к исполнению другой, имеющей более высокий приоритет. После выполнения высокоприоритетной задачи, контроллер возвращается к той, которой был занят до прерывания.

Представь, что ты — это микроконтроллер и ты очень занят важным делом — читаешь эту статью. Но внезапно начинает звонить твой телефон. Ты откладываешь статью и занимаешься обработкой этого прерывания — отвечаешь на звонок и ведешь беседу. Как только беседа завершена, ты возвращаешься к чтению статьи с того места, где прервался. Примерно так устроена обработка прерываний в микроконтроллере.

Попробуем применить прерывания для работы с энкодером. Нам потребуется сделать две вещи — настроить прерывание и написать функцию-обработчик прерывания.

Оставим схему прошлого эксперимента без изменений. Всё новое будет заключаться в программе. Рисунок 1. Электрическая принципиальная схема эксперимента

Рисунок 2. Монтажная схема эксперимента

Exp36.py

#include <LCDI2C_Multilingual.h>
 
#define ENC_A 13
#define ENC_B 12  
#define DEFAULT_I2C_ADDR 0x3F // Или 0x27 в зависимости от твоей платы IoT
 
LCDI2C_Generic lcd(DEFAULT_I2C_ADDR, 16, 2); 
 
bool states[4][2] = {
  {0,0},
  {1,0},
  {1,1},
  {0,1}
};
 
volatile int count = 0;
volatile int state = 0;
volatile int state_old = 0;
 
void printLcd(int number) {
  lcd.clear();
  lcd.print(number);
}
 
int index(bool a, bool b){
  for (int i = 0; i < 4; i++){
    if (states[i][0] == a and states[i][1] == b) {
      return i;
    }
  }
  return -1;
}
 
void ICACHE_RAM_ATTR callback() {
  bool value_a = digitalRead(ENC_A);
  bool value_b = digitalRead(ENC_B);
 
  state = index(value_a, value_b);
 
  if ((state - state_old == 1) or (state == 0 and state_old == 3)) {
    count++;
    if (not(count % 2)){
      Serial.println("+");
      printLcd(count / 2);
    }
    state_old = state;
  }
  else if ((state - state_old == -1)  or (state == 3 and state_old == 0)) {
    count--;
    if (not(count % 2)){
      Serial.println("-");
      printLcd(count / 2);
    }
    state_old = state;
  }
}
 
void setup() {
  lcd.init(); 
  lcd.setBacklight(0); 
  pinMode(ENC_A, INPUT);
  pinMode(ENC_B, INPUT);
 
  attachInterrupt(digitalPinToInterrupt(ENC_A), callback, CHANGE);
  attachInterrupt(digitalPinToInterrupt(ENC_B), callback, CHANGE);
}
 
void loop() {   
}

Сначала настраиваем прерывания:

  attachInterrupt(digitalPinToInterrupt(ENC_A), callback, CHANGE);
  attachInterrupt(digitalPinToInterrupt(ENC_B), callback, CHANGE);

Мы настроили при помощи указание события CHANGE, что при возникновении события изменения сигнала на выводах ENC_A и ENC_A с высокого на низкий или с низкого на высокий будет вызываться обработчик прерывания — функция callback.

Какие могут быть события:

• FALLING изменение с 1 на 0
• RISING изменение с 0 на 1
• CHANGE любое изменение
• LOW наличие логического 0
• HIGH_LEVEL наличие логической 1

Обратите внимание на новое ключевое слово volatile. Все переменные изменяемые из функции вызываемой прерыванием должны быть объявлены с этим ключевым словом. Необходимость обусловлена особенностями работой с памятью микроконтроллера.

volatile int count = 0;
volatile int state = 0;
volatile int state_old = 0;

Рассмотрим функцию-обработчик прерывания, она в свою очередь объявлена с атрибутом ICACHE_RAM_ATT. Причина аналогична указанной для переменных выше.

void ICACHE_RAM_ATTR callback() {
  bool value_a = digitalRead(ENC_A);
  bool value_b = digitalRead(ENC_B);
 
  state = index(value_a, value_b);
 
  if ((state - state_old == 1) or (state == 0 and state_old == 3)) {
    count++;
    if (not(count % 2)){
      Serial.println("+");
      printLcd(count / 2);
    }
    state_old = state;
  }
  else if ((state - state_old == -1)  or (state == 3 and state_old == 0)) {
    count--;
    if (not(count % 2)){
      Serial.println("-");
      printLcd(count / 2);
    }
    state_old = state;
  }
}

Она начинается с

  bool value_a = digitalRead(ENC_A);
  bool value_b = digitalRead(ENC_B);

Здесь мы впервые объявляем переменные внутри функции. По умолчанию, все переменные, созданные внутри функции доступны (имеют область видимости) в пределах именно этой функции. Как только функция завершается такие переменные уничтожаются. Такие переменные называются локальными, а объявленные в основной программе — глобальными.

Потом, как и раньше, мы определяем текущее состояние линий A и B энкодера. Определяем индекс состояния и проверяем можем ли мы сделать переход в данное состояние.

Как мы заметили ранее, при одном щелчке энкодера происходит смена двух состояний энкодера. Чтобы одному щелчку соответствовало изменение счетчика на 1, мы просто проверяем счетчик на четность.

    if (not(count % 2)){
      Serial.println("+");
      printLcd(count / 2);
    }

Если число четное (нет остатка от деления на 2) то пишем в терминал + и выводим число, деленное на 2 на дисплей.

Теперь самое главное. Обратим внимание на основной цикл программы. Мы в нем ничего не делаем. Все действия, связанные с работой с энкодером, происходят в обработчике прерывания и обрабатываются независимо от основной программы. В основном цикле мы можем заняться чем-то другим. В этом и смысл использования прерываний.